Esta imagen fue creada con POV-Ray.

Resumen

Esta imagen debería volverse a crear como imágenes vectoriales SVG. Esto proporciona muchas ventajas, véase Commons:Media for cleanup (en inglés) para más información. Si ya hay una versión SVG de esta imagen disponible, por favor súbala a Commons. Tras subirla, reemplace esta plantilla con la plantilla {{vector version available|nuevo nombre de imagen.svg}} en esta imagen.

Licencia

Yo, el titular de los derechos de autor de esta obra, lo libero al dominio público. Esto aplica en todo el mundo. En algunos países esto puede no ser legalmente factible; si ello ocurriese: Concedo a cualquier persona el derecho de usar este trabajo para cualquier propósito, sin ningún tipo de condición al menos que éstas sean requeridas por la ley.

Source

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing, and then cropped and compressed using pngcrush.

#include "colors.inc"

background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -250000>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5/10000
  }

light_source
  {
  <0, 200000, -500000>
  color White
  area_light <50000, 0, 0>, <0, 50000, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }

#declare r_tube = 0.07;  // thickness (radius) of tube

#declare sep = 0.2; // apparent height seperation between crossing rings

#declare shiny = finish {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 7.5
    }

#declare GREEN_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<cos(pi/6),sin(pi/6),0>+<0,.1,0>
  pigment { color rgb <0,0.75,0> }
  finish {shiny}
  }

#declare RED_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<-cos(pi/6),sin(pi/6),0> +<0,.1,0>
  pigment { color rgb <1,0,0> }
  finish {shiny}
  }

#declare BLUE_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<0,-1,0>+<0,.1,0>
  pigment { color rgb <0,0.25,1> }
  finish {shiny}
  }
  
object { RED_TORUS }
object { GREEN_TORUS }
object { BLUE_TORUS }  

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }

plane
  {
  <0,0,-1>, -0.33
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }