Resumen

Mathematica 11.0 code

rs[t_] := {-(E^(-2500 t^2)/(150 Sqrt[\[Pi]])) + t/3 - 1/3 t Erf[50 t],
    0, 0};
c = 1;
q = -1;
\[Beta][t_] := {(1 - Erf[50 t])/3, 0, 0};
d\[Beta][t_] := Chop@Evaluate@D[\[Beta][t1], t1] /. t1 -> t;

Plot[(\[Beta][t])[[1]], {t, -0.1, 0.1}, PlotRange -> All]
Plot[(d\[Beta][t])[[1]], {t, -0.1, 0.1}, PlotRange -> All]
\[Gamma][t_] := 1/Sqrt[1 - Norm[\[Beta][t]]^2];
n[r_, t_] := (r - rs[t])/Norm[r - rs[t]];
tr[r_, t_] := t - Norm[r - rs[t]]/c;
Ef[r_, t_] := (q (n[r, t] - \[Beta][t])/(\[Gamma][
      t]^2 (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]^2) + 
   q n[r, t] \[Cross]((n[r, t] - \[Beta][t])\[Cross]d\[Beta][t])/(
    c (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]) )
\[Tau] = 0.75;
StreamPlot[
 Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]], {x, -1, 1}, {y, -1, 
  1}, VectorPoints -> 20]
Bf[r_, t_] := (q (
    c (\[Beta][t]\[Cross]n[r, t]))/(\[Gamma][
      t]^2 (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]^2) + 
   q n[r, t] \[Cross](n[r, 
        t]\[Cross]((n[r, t] - \[Beta][t])\[Cross]d\[Beta][t]))/((1 - 
       n[r, t].\[Beta][t])^3 Norm[r - rs[t]]) )
S[r_, t_] := Ef[r, t]\[Cross]Bf[r, t]

p1 = Table[
   StreamDensityPlot[{Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]], 
     Log@Norm@Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]]}, {x, -2,
      1}, {y, -1, 1}, ColorFunction -> "SunsetColors", 
    StreamPoints -> Medium, StreamStyle -> {White}, PlotRange -> All, 
    Frame -> False, MaxRecursion -> 5, AspectRatio -> 2/3]
   , {\[Tau], -2.5, 1.5, 0.05}];

ListAnimate[p1]

Licencia

Yo, el titular de los derechos de autor de esta obra, la publico en los términos de la siguiente licencia:

Este archivo está disponible bajo la licencia Creative Commons Dedicación de Dominio Público CC0 1.0 Universal.

La persona que ha asociado una obra a este documento lo dedica al dominio público mediante la cesión mundial de sus derechos bajo la ley de derechos de autor y todos los derechos legales adyacentes propios de dicha, en el ámbito permitido por ley. Puedes copiar, modificar, distribuir y reproducir el trabajo, incluso con objetivos comerciales, sin pedir aprobación del autor. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

Este archivo, el cual fue publicado originalmente en https://twitter.com/j_bertolotti/status/1056921689643249666, fue revisado el 30 October 2018 por el revisor Ronhjones, quien confirmó que en esa fecha estaba disponible bajo la licencia indicada.