Archivo:Lagrangian points equipotential.gif

No se dispone de una resolución más alta.

Lagrangian_points_equipotential.gif ‎(512 × 384 píxeles; tamaño de archivo: 2 MB; tipo MIME: image/gif, bucleado, 72 frames, 7,2s)

Resumen

Descripción

English: Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple contours of equal potential). The potential was computed in POV-Ray using

$\Psi (x,y,z)={\Big (}x-{\frac {q}{1+q}}{\Big )}^{2}+y^{2}+{\frac {2}{(1+q){\sqrt {x^{2}+y^{2}+z^{2}}}}}+{\frac {2q}{(1+q){\sqrt {(x-1)^{2}+y^{2}+z^{2}}}}}$

for q = 0.1 and z = 0.^[1]

Fuente

Trabajo propio

Autor

cmglee

Otras versiones

POV-Ray source code

Lagrangian_points_equipotential.pov

Lagrangian_points_equipotential.ini

#declare rotation = clock;
// #declare rotation = -28;
#declare bounding_radius = 8;
#declare q = 0.1;
#declare q_plus_1 = q + 1;
#declare q_divide_q_plus_1 = q / q_plus_1;
#declare two_divide_q_plus_1 = 2 / q_plus_1;

union {
 isosurface {
  function {
   y + (pow(x-q_divide_q_plus_1,2) + z*z + two_divide_q_plus_1 * (q / sqrt((x-1)*(x-1)+z*z) + 1 / sqrt(x*x + z*z)))
  } 
  accuracy     0.001
  max_gradient 200 // increase to reduce artifact in funnel
  contained_by {sphere{0,bounding_radius}} open
  pigment {
   gradient <0,1,0>
   color_map {                                               [0.01 color rgb <0.5,0,0.75>][0.02 color rgb 1]
              [0.18 color rgb 1][0.19 color rgb <0.75,0.5,1>][0.21 color rgb <0.75,0.5,1>][0.22 color rgb 1]
              [0.38 color rgb 1][0.39 color rgb <0.75,0.5,1>][0.41 color rgb <0.75,0.5,1>][0.42 color rgb 1]
              [0.58 color rgb 1][0.59 color rgb <0.75,0.5,1>][0.61 color rgb <0.75,0.5,1>][0.62 color rgb 1]
              [0.78 color rgb 1][0.79 color rgb <0.75,0.5,1>][0.81 color rgb <0.75,0.5,1>][0.82 color rgb 1]
              [0.98 color rgb 1][0.99 color rgb <0.75,0.5,1>]                                               }
   scale 0.5
   translate <0,0.03,0>
  }
  scale     <1,0.5,1>
  translate <0,1.42,0>
 }
 union {
  sphere {0,0.2          pigment {rgbt <1,1,0,0.5>}   interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<1,0,0>,0.1    pigment {rgbt <0,0.5,1,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<q/2,0,0>,0.05 pigment {rgb  <0.5,0,0>} }
  union {
   torus    {1-q/2,0.02 translate <q/2,0,0>}
   cylinder {<-0.95,0,0>,<1.35,0,0>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,0.866>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,-0.866>,0.02}
   pigment  {rgb <0,0.75,0>}
  }
  union {
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L1" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.72,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L2" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <1.35,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L3" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <-0.95,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L4" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,0.866> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L5" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,-0.866> }
   pigment {rgb <1,0,0>}
  }
 }
 translate <-q/2,-0.14,0>
 rotate    <0,-rotation,0>
}
sky_sphere {pigment {rgb 1}}
light_source {<0,1,0>    color rgb 0.5 parallel point_at 0}
light_source {<0,10,-10> color rgb 1   shadowless}
camera {orthographic location <0.05,7.8,-10> look_at <0.05,-0.1,0> angle 13.8}

Antialias=off
Antialias_Threshold=0.01
Antialias_Depth=2

Input_File_Name="Lagrangian_points_equipotential.pov"

Initial_Frame=0
Final_Frame=71
Initial_Clock=0
Final_Clock=360

Cyclic_Animation=on
Pause_when_Done=off

↑ ZF Seidov, "The Roche Problem: Some Analytics", The Astrophysical Journal, 603:283-284, 2004 March 1

Licencia

Yo, titular de los derechos de autor de esta obra, la publico en los términos de las siguientes licencias:

Este archivo se encuentra bajo la licencia Creative Commons Genérica de Atribución/Compartir-Igual 3.0.

Eres libre:

de compartir – de copiar, distribuir y transmitir el trabajo
de remezclar – de adaptar el trabajo

Bajo las siguientes condiciones:

atribución – Debes otorgar el crédito correspondiente, proporcionar un enlace a la licencia e indicar si realizaste algún cambio. Puedes hacerlo de cualquier manera razonable pero no de manera que sugiera que el licenciante te respalda a ti o al uso que hagas del trabajo.
compartir igual – En caso de mezclar, transformar o modificar este trabajo, deberás distribuir el trabajo resultante bajo la misma licencia o una compatible como el original.

Se autoriza la copia, distribución y modificación de este documento bajo los términos de la licencia de documentación libre GNU, versión 1.2 o cualquier otra que posteriormente publique la Fundación para el Software Libre; sin secciones invariables, textos de portada, ni textos de contraportada. Se incluye una copia de la dicha licencia en la sección titulada Licencia de Documentación Libre GNU.

Puedes usar la licencia que prefieras.

Historial del archivo

Haz clic sobre una fecha y hora para ver el archivo tal como apareció en ese momento.

	Fecha y hora	Dimensiones	Usuario	Comentario
actual	23:57 22 oct 2021	512 × 384 (2 MB)	Cmglee	Increase resolution and framerate, rotate around barycentre, reframe image and make bodies transparent
	10:35 16 feb 2013	256 × 192 (709 kB)	Cmglee	Use 6-bit GIFs.
	10:06 16 feb 2013	256 × 192 (574 kB)	Cmglee	Fix shifting background colour.
	09:51 16 feb 2013	256 × 192 (574 kB)	Cmglee	Orbit around barycentre instead of Sun, darken every fifth contour and double number of frames.
	23:41 15 feb 2013	256 × 192 (354 kB)	Cmglee	{{Information \|Description ={{en\|1=Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple c...